home *** CD-ROM | disk | FTP | other *** search
/ Aminet 3 / Aminet 3 - July 1994.iso / Aminet / gfx / pbm / scripts.lha / netpbm / scripts / pstopnm < prev   
Encoding:
Text File  |  1993-01-27  |  8.1 KB  |  294 lines
  1. #!/bin/csh -f
  2. #
  3. #    Uses ghostscript to translate an Encapsulated PostScript file to
  4. #    Portable Anymap format file(s).
  5. #    pstopnm will create as many files as the number of pages in 
  6. #    the Postscript document.  The name of the files will be 
  7. #    psfile001.ppm, psfile002.ppm, etc.
  8. #    The ouput files will contain the area inside the BoundingBox.
  9. #    If BoundingBox parameters are not found in the PostScript
  10. #    document, default values are used.
  11. #
  12. #
  13. #       Usage: pstopnm [-forceplain] [-help] [-llx s] [-lly s] 
  14. #               [-urx s] [-ury s] [-nocrop] [-pbm|-pgm|-ppm] 
  15. #               [-verbose] [-xborder n] [-xmax n] [-xsize n] 
  16. #               [-yborder n] [-ymax n] [-ysize n] 
  17. #               [-portrait] [-landscape] psfile[.ps]
  18. # 
  19. #     Copyright (C) 1992 by Alberto Accomazzi, Smithsonian Astrophysical
  20. #    Observatory (alberto@cfa.harvard.edu).
  21. #
  22. #     Permission to use, copy, modify, and distribute this software and its
  23. #    documentation for any purpose and without fee is hereby granted, 
  24. #    provided that the above copyright notice appear in all copies and 
  25. #    that both that copyright notice and this permission notice appear 
  26. #    in supporting documentation.  This software is provided "as is" 
  27. #    without express or implied warranty.
  28. #
  29. set noglob
  30.  
  31. set progname = $0
  32. set progname = $progname:t
  33. set filtertail = "raw"
  34. set filterhead = "ppm"
  35. set xsize = 0
  36. set ysize = 0
  37. set xres = ""
  38. set yres = ""
  39.  
  40. # default values: max image x and y sizes
  41. set xmax = 612
  42. set ymax = 792
  43. # default values: image area fits in a 8.5x11 sheet with 1 inch border
  44. set llx = 72
  45. set lly = 72
  46. set urx = 540
  47. set ury = 720
  48. # default values: x and y borders are 10% of x and y size
  49. set xborder = "0.1"
  50. set yborder = "0.1"
  51. # default values: orientation is unknown
  52. set orient = 0
  53.  
  54. set psfile = ""
  55. set USAGE = "Usage: $progname [-forceplain] [-help] [-llx s] [-lly s]\
  56. [-urx s] [-ury s] [-landscape] [-portrait]\
  57. [-nocrop] [-pbm|-pgm|-ppm] [-verbose] [-xborder s] [-xmax s]\
  58. [-xsize s] [-yborder s] [-ymax s] [-ysize s] psfile[.ps]"
  59. alias usage 'echo $USAGE; exit 1'
  60.  
  61. while ($#argv > 0)
  62.     switch ($argv[1])
  63.     case -h*:   # -help
  64.         usage
  65.         breaksw
  66.     case -pbm:
  67.     case -pgm:
  68.     case -ppm:
  69.         set filterhead = `echo "$argv[1]" | sed "s/-//1"`
  70.     breaksw
  71.     case -llx:
  72.         shift argv
  73.         if ($#argv == 0) eval usage
  74.         set llx = `(echo "scale=4";echo "$argv[1] * 72")|bc -l`
  75.     set nobb
  76.     breaksw
  77.     case -lly:
  78.         shift argv
  79.         if ($#argv == 0) eval usage
  80.     set lly = `(echo "scale=4";echo "$argv[1] * 72")|bc -l`
  81.     set nobb
  82.     breaksw
  83.     case -urx:
  84.         shift argv
  85.         if ($#argv == 0) eval usage
  86.     set urx = `(echo "scale=4";echo "$argv[1] * 72")|bc -l`
  87.     set nobb
  88.     breaksw
  89.     case -ury:
  90.         shift argv
  91.         if ($#argv == 0) eval usage
  92.     set ury = `(echo "scale=4";echo "$argv[1] * 72")|bc -l`
  93.     set nobb
  94.     breaksw
  95.     case -no*:    # -nocrop
  96.     set nocrop
  97.     breaksw
  98.     case -xs*:    # -xsize
  99.         shift argv
  100.         if ($#argv == 0) eval usage
  101.     @ xsize = $argv[1]
  102.     breaksw
  103.     case -ys*:    # -ysize
  104.         shift argv
  105.         if ($#argv == 0) eval usage
  106.     @ ysize = $argv[1]
  107.     breaksw
  108.     case -xm*:    # -xmax
  109.         shift argv
  110.         if ($#argv == 0) eval usage
  111.     @ xmax = $argv[1]
  112.     breaksw
  113.     case -ym*:    # -ymax
  114.         shift argv
  115.         if ($#argv == 0) eval usage
  116.     @ ymax = $argv[1]
  117.     breaksw
  118.     case -xb*:    # -xborder
  119.         shift argv
  120.         if ($#argv == 0) eval usage
  121.     set xborder = $argv[1]
  122.     breaksw
  123.     case -yb*:    # -yborder
  124.         shift argv
  125.         if ($#argv == 0) eval usage
  126.     set yborder = $argv[1]
  127.     breaksw
  128.     case -f*:    # -forceplain
  129.     set filtertail = ""
  130.     breaksw
  131.     case -v*:    # -verbose
  132.     set verb
  133.     breaksw
  134.     case -po*:    # -portrait
  135.     set orient = 1
  136.     breaksw
  137.     case -la*:    # -landscape
  138.     set orient = 2
  139.     breaksw
  140.     case -*:
  141.         echo "${progname}: Unknown option $argv[1]"
  142.         usage
  143.         breaksw
  144.     default:    # input file
  145.     set psfile = $argv[1]
  146.     set ppmfile = `basename $argv[1] .ps`
  147.         breaksw
  148.     endsw
  149.     shift argv
  150. end
  151.  
  152. if ($psfile =~ "") eval usage
  153. if (! -f $psfile) then
  154.     echo "${progname}: file $psfile not found"
  155.     usage
  156. endif
  157.  
  158. set bb = `grep "%%BoundingBox" $psfile`
  159. if ($?nobb == 0 && $#bb == 5) then
  160.     set llx = $bb[2]
  161.     set lly = $bb[3]
  162.     set urx = $bb[4]
  163.     set ury = $bb[5]
  164. else
  165.     if ($?nobb == 0) \
  166.         echo "${progname}: warning: BoundingBox not found in input file"
  167. endif
  168.  
  169. set tmpsx = `(echo "scale=4";echo "$urx - $llx")|bc -l`
  170. set tmpsy = `(echo "scale=4";echo "$ury - $lly")|bc -l`
  171.  
  172. # see if orientation was specified 
  173. if ($orient == 0) then
  174.     # no orientation was specified; compute default orientation
  175.     set tmpx = 0
  176.     set tmpy = 0
  177.     set tmpsx1 = $tmpsx:r
  178.     set tmpsy1 = $tmpsy:r
  179.     # default is landscape mode
  180.     set orient = 2
  181.     if ($xsize == 0 && $ysize == 0) then
  182.     set tmpx = $xmax
  183.     set tmpy = $ymax
  184.     else
  185.     if ($xsize != 0) set tmpx = $xsize
  186.     if ($ysize != 0) set tmpy = $ysize
  187.     endif
  188.     if ($tmpx == 0 || $tmpy == 0) then
  189.     # only one size was specified
  190.     if ($tmpsy1 > $tmpsx1) set orient = 1
  191.     else
  192.     # no size or both sizes were specified
  193.     if ($tmpsy1 > $tmpsx1 && $tmpy > $tmpx) set orient = 1
  194.     if ($tmpsx1 > $tmpsy1 && $tmpx > $tmpy) set orient = 1
  195.     endif
  196. endif
  197.  
  198. # now reset BoundingBox llc and total size to take into account margin
  199. set llx = `(echo "scale=4";echo "$llx - $tmpsx * $xborder")|bc -l`
  200. set lly = `(echo "scale=4";echo "$lly - $tmpsy * $yborder")|bc -l`
  201. set urx = `(echo "scale=4";echo "$urx + $tmpsx * $xborder")|bc -l`
  202. set ury = `(echo "scale=4";echo "$ury + $tmpsy * $yborder")|bc -l`
  203. # compute image area size 
  204. set sx = `(echo "scale=4";echo "$tmpsx + 2 * $xborder * $tmpsx")|bc -l`
  205. set sy = `(echo "scale=4";echo "$tmpsy + 2 * $yborder * $tmpsy")|bc -l`
  206.     
  207. if ($orient != 1) then
  208.     # render image in landscape mode
  209.     set tmpsx = $sx
  210.     set sx = $sy
  211.     set sy = $tmpsx
  212. endif
  213.  
  214. # if xsize or ysize was specified, compute resolution from them
  215. if ($xsize != 0) set xres = `(echo "scale=4";echo "$xsize *72 / $sx")|bc -l`
  216. if ($ysize != 0) set yres = `(echo "scale=4";echo "$ysize *72 / $sy")|bc -l`
  217.  
  218. if ($xres =~ "" && $yres !~ "") then
  219.     # ysize was specified, xsize was not; compute xsize based on ysize
  220.     set xres = $yres 
  221.     set xsize = `(echo "scale=4";echo "$sx * $xres /72 + 0.5")|bc -l`
  222.     set xsize = $xsize:r
  223. else 
  224.     if ($yres =~ "" && $xres !~ "") then
  225.     # xsize was specified, ysize was not; compute ysize based on xsize
  226.         set yres = $xres
  227.         set ysize = `(echo "scale=4";echo "$sy * $yres /72 + 0.5")|bc -l`
  228.         set ysize = $ysize:r
  229.     else
  230.     if ($xres =~ "" && $yres =~ "") then
  231.             # neither xsize nor ysize was specified; compute them from
  232.         # xmax and ymax
  233.         set xres = `(echo "scale=4";echo "$xmax *72/$sx")|bc -l`
  234.         set yres = `(echo "scale=4";echo "$ymax *72/$sy")|bc -l`
  235.         set xres = `(echo "scale=4";echo "if($xres>$yres)$yres";echo "if($yres>$xres)$xres")|bc -l`
  236.         set yres = $xres
  237.         if ($?nocrop) then
  238.         # keep output file dimensions equal to xmax and ymax
  239.         set xsize = $xmax
  240.         set ysize = $ymax
  241.         else
  242.                 set xsize = `(echo "scale=4";echo "$sx * $xres /72+0.5")|bc -l`
  243.                 set ysize = `(echo "scale=4";echo "$sy * $yres /72+0.5")|bc -l`
  244.         endif
  245.             set xsize = $xsize:r
  246.             set ysize = $ysize:r
  247.     endif
  248.     endif
  249. endif
  250.  
  251. # translate + rotate image, if necessary
  252. if ($orient == 1) then
  253.     # portrait mode
  254.     # adjust offsets
  255.     set llx = `(echo "scale=4";echo "$llx - ($xsize *72/$xres - $sx)/2")|bc -l`
  256.     set lly = `(echo "scale=4";echo "$lly - ($ysize *72/$yres - $sy)/2")|bc -l`
  257.     set pstrans = "$llx neg $lly neg translate"
  258. else
  259.     # landscape mode
  260.     # adjust offsets
  261.     set llx = `(echo "scale=4";echo "$llx - ($ysize *72/$yres - $sy)/2")|bc -l`
  262.     set ury = `(echo "scale=4";echo "$ury + ($xsize *72/$xres - $sx)/2")|bc -l`
  263.     set pstrans = "90 rotate $llx neg $ury neg translate"
  264. endif
  265.  
  266.  
  267. if ($?verb) then
  268.     echo "sx = $sx"
  269.     echo "sy = $sy"
  270.     echo "xres  = $xres"
  271.     echo "yres  = $yres"
  272.     echo "xsize = $xsize"
  273.     echo "ysize = $ysize"
  274.     echo -n "orientation "
  275.     if ($orient == 1) then 
  276.     echo "portrait"
  277.     else
  278.     echo "landscape"
  279.     endif
  280.     echo "PS header: $pstrans"
  281. endif
  282.  
  283. echo "${progname}: writing $filterhead file(s)"
  284.  
  285. echo $pstrans | \
  286.     gs -sDEVICE=${filterhead}${filtertail} \
  287.        -sOutputFile=$ppmfile%03d.$filterhead \
  288.        -g${xsize}x${ysize} \
  289.        -r${xres}x${yres} \
  290.        -q - $psfile 
  291.  
  292.  
  293.  
  294.